Muestreo Estratificado Proporcional con SAS
Antes que nada, quiero aclarar que lo que pretendo mostrar con este ejemplo es como calcular una muestra de tamaño n que siga la misma distribución de la población original. Los grupos, subpoblaciones, estratos que utilizaremos para crear esta muestra no necesariamente siguen la definición clásica del muestreo estratificado.
Ahora bien, vamos con un poco de teoría:
Según Wikipedia “El muestreo estratificado consiste en la división previa de la población de estudio en grupos o clases que se suponen homogéneos respecto a característica a estudiar. A cada uno de estos estratos se le asignaría una cuota que determinaría el número de miembros del mismo que compondrán la muestra. Dentro de cada estrato se suele usar la técnica de muestreo sistemático, ya que con aquella suelen ser las técnicas más usadas en la practica.
Según la cantidad de elementos de la muestra que se han de elegir de cada uno de los estratos, existen dos técnicas de muestreo estratificado:
Asignación proporcional: el tamaño de cada estrato en la muestra es proporcional a su tamaño en la población.
Asignación óptima: la muestra recogerá más individuos de aquellos estratos que tengan más variabilidad. Para ello es necesario un conocimiento previo de la población.
Por ejemplo, para un estudio de opinión, puede resultar interesante estudiar por separado las opiniones de hombres y mujeres pues se estima que, dentro de cada uno de estos grupos, puede haber cierta homogeneidad. Así, si la población está compuesta de un 55% de mujeres y un 45% de hombres, se tomaría una muestra que contenga también esa misma proporción.”
Ok, ahora veamos como lo hacemos (al menos como yo lo hago) en SAS:
-Para este ejemplo vamos a usar el dataset sashelp.shoes, la muestra que necesitamos es de 10% del total de la población.
/* 1) Necesitamos saber los pesos de los grupos que vamos a utilizar como estratos, en este ejemplo vamos a usar la variable Region.*/
proc freq data=sashelp.shoes noprint;
table region /missing out=strata_counts(drop= percent rename=(count=_nsize_));
run;
/*
2) Ahora calculamos el tamaño de la muestra que sabemos que es de 10%. Pueden darse cuenta que el redondeo lo estoy haciendo hacia arriba, pero la verdad es a juicio del facultativo
*/
data strata_counts2;
set strata_counts;
_nsize_ = ceil(_nsize_*0.10);
run;
/*
3) Usando Surveyselect y con la información anterior calculamos nuestra muestra
*/
Proc Surveyselect data=sashelp.shoes sampsize=strata_counts2 out=sample ;
strata region;run;
/*
4) Graficos la distribucion de la población y de la muestra para constatar que relativamente siguen la misma distribución.
*/
title “Distribucion de la Poblacion”;
PROC GCHART DATA=sashelp.shoes;
VBAR3D Region /
SHAPE=BLOCK
FRAME TYPE=FREQ
pct
COUTLINE=BLACK
RAXIS=AXIS1
MAXIS=AXIS2
PATTERNID=MIDPOINT
;
RUN;QUIT;
title “Distribucion de la Muestra”;
PROC GCHART DATA=sample;
VBAR3D Region /
SHAPE=BLOCK
FRAME TYPE=freq
pct
COUTLINE=BLACK
RAXIS=AXIS1
MAXIS=AXIS2
PATTERNID=MIDPOINT
;
RUN;QUIT;
SASludos,
Alberto
